How to create a dynamic control array with 100 commandbuttons?

[liangchu]

Hi, I want to make a new dynamic control array with 100 commandbuttons.But I don't know how to do it?thanks a lot.

[mstraf]

put a button in your form, and set its Index property to 0
Then in the form load:

    Dim k As Long
    For k = 1 To 99
        Load myButton(k)
        With myButton(k)
            '' set here position, caption and other properties
            .Visible = True
        End With
    Next

[Hack]

Or

Option Explicit

Private WithEvents myButton As VB.CommandButton

Private Sub Command1_Click()
Dim k As Long
    For k = 1 To 99
        Set myButton = Controls.Add("VB.CommandButton", _
                    "myButton" & k, Form1)
        With myButton
          'set here position, caption and other properties
            .Visible = True
        End With
    Next
End Sub

[mstraf]

Hack, that code will fire the events only for the last command button added to the form, that is the last time the myButton variable has been assigned.

Getting events from an array of dynamically added controls (like in your code) is possible, but is also e royal pain (for example using a collection of classes, one of each control that was added)

This is why I suggested to use the Load method (that, unlike yours, does create an 'array' :-) ) I do indeed us the Controls.Add method, but only for my own controls, because I that case I need only an event sync class, but I am afraid will go off topic. This is a very interesting issue in VB6, that fortunately has been fixed in .net

[Hack]

I ran into problems using your example (although I can't remember what now)

[mstraf]

Open VB, create a new exe project and cut and paste the code below
Add a button in the Form, call it "myButton" and set its Index property to 0 (carefull, not the TabIndex property...), move the button at position 0,0
Run the project and click on any button to see the event
Let me know if you get any trouble.
Have fun!

Option Explicit

Private Sub Form_Load()
    Dim k As Long
    For k = 1 To 99
        Load myButton(k)
        With myButton(k)
            .Left = k * 120
            .Top = k * 120
            .Visible = True
        End With
    Next
End Sub

Private Sub myButton_Click(Index As Integer)
    Debug.Print "Button " & Index
End Sub

[Keithuk]

100 command buttons what a confusing app?

[mukharjee]

This works great for me. Thanks. If we dynamically create object using me.control.add click event is working only for the last control. but the following code works good to handle events. Once again thanks to mstraf

Option Explicit

Private Sub Form_Load()
    Dim k As Long
    For k = 1 To 99
        Load myButton(k)
        With myButton(k)
            .Left = k * 120
            .Top = k * 120
            .Visible = True
        End With
    Next
End Sub

Private Sub myButton_Click(Index As Integer)
    Debug.Print "Button " & Index
End Sub

[/QUOTE]