Separate this function?

[WeightOver2001]

Private Sub Form_Load()
MsgBox GetFiles("c:\")
End Sub
Function GetFiles(ByVal MyPath As String) As String
Dim sFiles As String
   MyName = Dir(MyPath)
   Do While MyName <> ""
        Select Case UCase(Right(MyName, 3))
            Case "TXT", "CSV", "CHM"
                sFiles = sFiles & MyName & vbCr
            Case Else
        End Select
        MyName = Dir()   '
   Loop
   GetFiles = sFiles & vbCrLf
End Function

Right now if i msgbox Getfiles()then it msgboxs all the names under one msgbox instead of multiple msgboxs.

[Ron Weller]

This should work!

Private Sub Form_Load()
   Dim I As Long
   Dim Files() As String
   
   Files = Split(GetFiles("c:\"), vbCr)
   For I = Lbound(Files) to UBound(Files) - 1
      MsgBox Files(I)
   Next I

   Erase Files
End Sub

Function GetFiles(ByVal MyPath As String) As String
   Dim sFiles As String
   MyName = Dir(MyPath)
   Do While MyName <> ""
      Select Case UCase(Right(MyName, 3))
      Case "TXT", "CSV", "CHM"
         sFiles = sFiles & MyName & vbCr
      End Select
      MyName = Dir()   '
   Loop
   GetFiles = sFiles & vbCrLf
End Function

[WeightOver2001]

instead of doing it like is there anyway to split it within the GetFiles() func?

[Ron Weller]

Sure!

Private Sub Form_Load()
   Dim I As Long
   Dim Files() As String
   
   Files = GetFiles("c:\")
   For I = LBound(Files) To UBound(Files)
      MsgBox Files(I)
   Next I
   Erase Files
End Sub

Function GetFiles(ByVal MyPath As String) As String()
   Dim MyName As String
   Dim Files() As String
   Dim fc As Long
   
   MyName = Dir(MyPath)
   Do While MyName <> ""
      Select Case UCase(Right(MyName, 3))
      Case "TXT", "CSV", "CHM"
         fc = fc + 1
         ReDim Preserve Files(1 To fc)
         Files(fc) = MyName
      End Select
      MyName = Dir()
   Loop
   GetFiles = Files()
   Erase Files
End Function

[Ron Weller]

it works alright when the path is just c:\.

but i get a subscript range error if i change it,
Files = GetFiles("c:\" + "Programming Files")

That is because you selected a folder that did not have any files that matched your criteria. Here is a version that looks for that:

Private Sub Form_Load()
   Dim I As Long
   Dim Files() As String
   
   Files = GetFiles("c:\programming files")
   For I = LBound(Files) To UBound(Files)
      MsgBox Files(I)
   Next I
   Erase Files
End Sub

Function GetFiles(ByVal MyPath As String) As String()
   Dim MyName As String
   Dim Files() As String
   Dim fc As Long
   
   MyName = Dir(MyPath)
   Do While MyName <> ""
      Select Case UCase(Right(MyName, 3))
      Case "TXT", "CSV", "CHM"
         fc = fc + 1
         ReDim Preserve Files(1 To fc)
         Files(fc) = MyName
      End Select
      MyName = Dir()
   Loop
   If fc = 0 Then Files = Split("")
   GetFiles = Files()
   Erase Files
End Function